Initial commit: abyssVpn project

- Tauri desktop app (apps/desktop)
- Python Django API service (services/api)
- Deployment scripts and docs

deploy/07_deploy_api.bat

@@ -0,0 +1,27 @@
+@echo off
+setlocal
+call "%~dp0config.bat"
+
+set "API_ZIP=%TEMP%\abyssinfo-api.zip"
+
+echo [AbyssInfo] Packaging Django API ...
+powershell -NoProfile -ExecutionPolicy Bypass -File "%~dp0scripts\package_api.ps1" ^
+  -ProjectRoot "%~dp0.." ^
+  -OutputZip "%API_ZIP%"
+if errorlevel 1 exit /b 1
+
+echo [AbyssInfo] Uploading Django API package and deploy script ...
+%SCP_BASE% "%API_ZIP%" %SERVER_USER%@%SERVER_HOST%:/tmp/abyssinfo-api.zip
+if errorlevel 1 exit /b 1
+
+%SCP_BASE% "%~dp0remote\deploy_api.sh" %SERVER_USER%@%SERVER_HOST%:/tmp/abyssinfo_deploy_api.sh
+if errorlevel 1 exit /b 1
+
+echo [AbyssInfo] Deploying Django API ...
+%SSH_BASE% "chmod +x /tmp/abyssinfo_deploy_api.sh && REMOTE_APP_DIR=%REMOTE_APP_DIR% API_DOMAIN=%API_DOMAIN% API_LEGACY_DOMAIN=%API_LEGACY_DOMAIN% NETMAKER_BASE_DOMAIN=%NETMAKER_BASE_DOMAIN% /tmp/abyssinfo_deploy_api.sh"
+if errorlevel 1 (
+  echo [AbyssInfo] Django API deployment failed.
+  exit /b 1
+)
+
+echo [AbyssInfo] Django API deployment completed.